Help
This Answer shows you how to use a technique called "Wiggle Stereoscopy" to create 3D-ish images like this one:
In wiggle stereoscopy, the 2 images are aligned so that the "subject" overlaps, and then the right and left images are alternated quickly. Past a certain frequency, the brain interprets the alternations as parallax motion, which creates the illusion of depth. (It's important to note that this is not really a 3D image, but rather a visual trick. True 3D is more complex.)
The first step is to take 2 photographs; fairly simple objects work best. Take the first picture of the object and then (and this is the important part!) slide the camera to the other eye and take the same picture, but at an offset. This is the tricky part -- you don't want to change the angle of the camera or move your position in any way. You simply want to slide the camera from one eye to the other, keeping the lens in the same plane. With practice, you'll get the hang of it. (And, of course, there are also special cameras you can buy, like this 3D camera from Fuji). Once you have the images, you can use this Processing script at the bottom of the page to align the subjects and then export the image to an animated Gif. (You'll need to install the gifAnimation Processing Library.)
Here's an example. I took these two images of my son's tricycle. Here's the right hand image:
And here's the left hand image:
I imported them into iPhoto, and then exported them on the medium size setting, naming them "tricycle_r.png" and "tricycle_l.png" respectively. I then used the Processing script at the end of this post to align and fuse the images. Use the "k" and "l" keys to move the image to the left and right, and the "q" and "a" keys to move the image up and down. The goal is to superimpose the subject of the two images (i.e., the tricycle) on top of each other. When you get it right, the image will suddenly pop off the screen, as shown in this example:
Once the alignment is right, press "e" to export an animated gif. (Remember to install the gifAnimation library). Here's the final example, as well as a few more pictures I've created. You'll quickly see why this is called "wiggle stereoscopy"!
A cactus:
A toy firetruck:
Here's the Processing script. Hope you enjoy it, and look forward to seeing your own examples in the comments.
//Be sure to insall gifAnimation library from:
// http://www.extrapixel.ch/processing/gifAnimation/
//
import gifAnimation.*;
PImage left = loadImage("/Users/odewahn/Desktop/cactus_l.png");
PImage right = loadImage("/Users/odewahn/Desktop/cactus_r.png");
int rx = 0; // Horizontal offset for the right image
int ry = 0; // Vertical offest for the right image
int pause = 75; //Number of MS to pause b/t left and right images
int rflag = -1; // toggle that controls which to display
//Set up drawing area
void setup() {
size(left.width, left.height);
}
void exportGif() {
// Set up the gif
GifMaker gifExport = new GifMaker(this, "/Users/odewahn/Desktop/out.gif");
gifExport.setSize(width-abs(rx), height-abs(ry)); //Sets a clip region
gifExport.setRepeat(0); //Make this repeat infinitely
gifExport.setDelay(75); //Set the pause rate to 75ms b/t images
// Draw the right image
image(right,rx,ry);
gifExport.addFrame();
//Draw the left frame
image(left,0,0);
gifExport.addFrame();
//Save the file
gifExport.finish();
}
//Simple control scheme
void keyPressed() {
switch (key) {
case 'q': //shift up
ry -= 2;
break;
case 'a': //shift down
ry += 2;
break;
case 'l':
rx += 2; //shift right
break;
case 'k':
rx -= 2; //shift left
break;
case '1':
pause = 75; //fast display mode
break;
case '2': //slow display mode
pause = 500;
break;
case 'e': //export an animated gif
exportGif();
break;
}
}
void draw() {
delay(pause);
println(rx + " , " + ry);
if (rflag == -1) {
image(right,rx,ry); //Draw the right image at the current offest position
} else {
image (left,0,0); //Draw the left image
}
rflag *= -1; // toggle the image
}
